/*
 * Proyek: IoT Pendeteksi Hujan & Pengaman Jemuran Otomatis
 * Board : Wemos D1 Mini (ESP8266)
 */

// Konfigurasi Blynk (Harus diletakkan paling atas)
#define BLYNK_TEMPLATE_ID "TMPL6zGCVNiNo" // Ganti dengan Template ID Blynk
#define BLYNK_TEMPLATE_NAME "MONITORINGHUJAN" // Ganti dengan Template Name BLynk
#define BLYNK_AUTH_TOKEN "vi0OTtXX9CaNS6Hq5UvcO-2Bd4k8OXrd"; // Ganti dengan TOKEN BLYNK

// --- Include Library ---
#include <ESP8266WiFi.h>
#include <BlynkSimpleEsp8266.h>
#include <Servo.h>
#include <LiquidCrystal_I2C.h>
#include <ESP8266HTTPClient.h>
#include <WiFiClientSecure.h>

// --- Konfigurasi WiFi ---
char ssid[] = "XXXXXXXXXXXX";       // Ganti dengan nama WiFi Anda
char pass[] = "XXXXXXXXXXXX";   // Ganti dengan password WiFi Anda

// --- Konfigurasi Fonnte API ---
String fonnteToken = "xxxxxxxxxxxx"; // Ganti dengan Token API WA
String targetWA = "08xxxxxxxxxxxx"; // Ganti dengan Nomor WA tujuan (awali 08)

// --- Definisi Pin Wemos D1 Mini ---
#define RAIN_SENSOR_PIN D5  // Pin Digital Sensor Hujan
#define SERVO_PIN D6        // Pin PWM Servo SG90
#define BUZZER_PIN D7       // Pin Buzzer

// --- Inisialisasi Objek ---
Servo myServo;
LiquidCrystal_I2C lcd(0x27, 16, 2); 
BlynkTimer timer;

// --- Variabel State ---
bool isRaining = false; 

// Variabel Timer Buzzer (menggunakan millis)
unsigned long buzzerStartTime = 0;
bool isBuzzerOn = false;

// Variabel Debounce
int dryCount = 0;
int wetCount = 0;
const int DRY_THRESHOLD = 5; // 5x pembacaan = 10 detik
const int WET_THRESHOLD = 2; // 2x pembacaan = 4 detik

// --- Fungsi Menggerakkan Servo Perlahan ---
void moveServoSlow(int targetAngle) {
  int currentAngle = myServo.read();
  if (currentAngle < targetAngle) {
    for (int pos = currentAngle; pos <= targetAngle; pos += 1) {
      myServo.write(pos);
      delay(15); 
    }
  } else {
    for (int pos = currentAngle; pos >= targetAngle; pos -= 1) {
      myServo.write(pos);
      delay(15);
    }
  }
}

void setup() {
  Serial.begin(115200);
  
  pinMode(RAIN_SENSOR_PIN, INPUT);
  pinMode(BUZZER_PIN, OUTPUT);
  digitalWrite(BUZZER_PIN, LOW); 
  
  myServo.attach(SERVO_PIN);
  myServo.write(0); 

  lcd.init();
  lcd.backlight();
  lcd.setCursor(0, 0);
  lcd.print("Sistem Jemuran");
  lcd.setCursor(0, 1);
  lcd.print("Menghubungkan...");

  Blynk.begin(BLYNK_AUTH_TOKEN, ssid, pass);

  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("WiFi Connected!");
  delay(2000);
  
  timer.setInterval(2000L, checkRainStatus);
  
  updateDisplay("Sistem Aktif", "Cerah - Aman");
  Blynk.virtualWrite(V1, "Sistem Aktif - Cuaca Cerah"); 
}

void loop() {
  Blynk.run();
  timer.run();

  // Mengecek apakah buzzer sudah menyala selama 5 detik (5000 ms)
  if (isBuzzerOn && (millis() - buzzerStartTime >= 5000)) {
    digitalWrite(BUZZER_PIN, LOW); // Matikan buzzer
    isBuzzerOn = false;            // Reset status buzzer
    Serial.println("Buzzer dimatikan otomatis setelah 5 detik.");
  }
}

// --- Fungsi Mengecek Status Hujan ---
void checkRainStatus() {
  int sensorValue = digitalRead(RAIN_SENSOR_PIN); 

  if (sensorValue == LOW) { 
    wetCount++;
    dryCount = 0;
  } else { 
    dryCount++;
    wetCount = 0;
  }

  Serial.print("[DEBUG] Sensor: ");
  Serial.print(sensorValue == LOW ? "BASAH (0)" : "KERING (1)");
  Serial.print(" | Wet: "); Serial.print(wetCount); Serial.print("/"); Serial.print(WET_THRESHOLD);
  Serial.print(" | Dry: "); Serial.print(dryCount); Serial.print("/"); Serial.print(DRY_THRESHOLD);
  Serial.print(" | Status: "); Serial.println(isRaining ? "HUJAN" : "CERAH");

  bool newRainStatus = isRaining;

  if (wetCount >= WET_THRESHOLD && !isRaining) {
    newRainStatus = true;
  } else if (dryCount >= DRY_THRESHOLD && isRaining) {
    newRainStatus = false;
  }

  if (newRainStatus != isRaining) {
    isRaining = newRainStatus; 

    if (isRaining) {
      Serial.println("Hujan Terdeteksi!");
      updateDisplay("Status: HUJAN!", "Jemuran Ditarik");
      Blynk.virtualWrite(V1, "HUJAN! Jemuran diamankan."); 
      
      digitalWrite(BUZZER_PIN, HIGH); 
      buzzerStartTime = millis(); // Catat waktu mulai bunyi
      isBuzzerOn = true;          // Tandai buzzer sedang bunyi
      
      moveServoSlow(180); 
      sendWhatsApp("Peringatan! Hujan turun, jemuran telah ditarik otomatis.");
      
    } else {
      Serial.println("Hujan Reda.");
      digitalWrite(BUZZER_PIN, LOW); 
      isBuzzerOn = false; // Pastikan status buzzer direset
      
      updateDisplay("Status: CERAH", "Jemuran Keluar");
      Blynk.virtualWrite(V1, "CERAH. Jemuran dikeluarkan."); 
      
      moveServoSlow(0); 
      sendWhatsApp("Info Cuaca: Hujan telah reda, jemuran dijemur kembali.");
    }
  }
}

// --- Fungsi Update LCD ---
void updateDisplay(String baris1, String baris2) {
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print(baris1);
  lcd.setCursor(0, 1);
  lcd.print(baris2);
}

// --- Fungsi Kirim Pesan WA ---
void sendWhatsApp(String message) {
  if (WiFi.status() == WL_CONNECTED) {
    WiFiClientSecure client;
    client.setInsecure(); 
    HTTPClient http;
    
    http.begin(client, "https://api.fonnte.com/send");
    http.addHeader("Authorization", fonnteToken);
    http.addHeader("Content-Type", "application/x-www-form-urlencoded");

    String postData = "target=" + targetWA + "&message=" + message;

    Serial.println("Mengirim WA...");
    int httpResponseCode = http.POST(postData);

    if (httpResponseCode > 0) {
      Serial.print("WA Terkirim. Code: ");
      Serial.println(httpResponseCode);
    } else {
      Serial.print("Error WA: ");
      Serial.println(httpResponseCode);
    }
    http.end();
  }
}